【MQL5】動的かつ5次元以上の配列を作成する方法-構造体ネスト

はじめに
MQL5の配列制限について
1. 公式の制限
2. なぜ高次元配列が必要なのか？
構造体ネストによる解決方法
1. 基本的な構造体定義
2. 5次元配列の実装例
まとめ

はじめに

MQL5では公式に1次元目が動的な最大4次元までの配列しかサポートされていませんが、構造体のネスト（入れ子構造）を使うことで、すべての次元を動的かつ5次元以上の疑似多次元配列を実現することができます。

この記事では、構造体ネストを使った高次元配列の実装方法を詳しく解説します。

WAN

発想力でMQLの限界を超えるのだ(‘ω’)

MQL5の配列制限について

公式の制限

MQL5では以下のような制限があります：

// MQL5公式サポート: 最大4次元まで
double matrix[][10][20][5]; // これが最大
ArrayResize(matrix, 3);

// 5次元以上は直接サポートされていない
// double invalid_matrix[][][][][][]; // エラー

WAN

さらに動的といっても1次元目のみ動的で、それ以降の次元数は静的であるのが原則。

今回紹介する方法を使えば、2次元目以降も動的な設定が可能だよ(‘ω’)

なぜ高次元配列が必要なのか？

複雑な金融データ分析では、以下のような多次元データを扱う必要があります：

通貨ペア × 時間足 × 指標 × 期間 × 値の種類
ポートフォリオ × 資産 × リスク指標 × 時系列 × シナリオ

これらを効率的に管理するために、高次元配列が有効です。

構造体ネストによる解決方法

基本的な構造体定義

//+------------------------------------------------------------------+
//| 5次元配列のための構造体定義                                      |
//+------------------------------------------------------------------+
struct Level1
  {
   string            data[];           // 最内層：データ配列
  };

struct Level2
  {
   Level1            rows[];           // 2次元：行の配列
  };

struct Level3
  {
   Level2            pages[];          // 3次元：ページの配列
  };

struct Level4
  {
   Level3            volumes[];        // 4次元：ボリュームの配列
  };

struct Level5
  {
   Level4            books[];          // 5次元：ブックの配列
  };

5次元配列の実装例

//+------------------------------------------------------------------+
//| 5次元配列の実装と使用例                                          |
//+------------------------------------------------------------------+
void OnStart()
  {
   Level5 array_5d;

   Print("=== 5次元配列の実装例 ===");

   // 配列サイズの定義: [2][3][4][5][6]
   int book_size = 2;
   int volume_size = 3;
   int page_size = 4;
   int row_size = 5;
   int data_size = 6;
   
   // 最外層から順番に配列を初期化
   ArrayResize(array_5d.books, book_size);

   for(int book = 0; book < book_size; book++)
     {
      ArrayResize(array_5d.books[book].volumes, volume_size);

      for(int volume = 0; volume < volume_size; volume++)
        {
         ArrayResize(array_5d.books[book].volumes[volume].pages, page_size);

         for(int page = 0; page < page_size; page++)
           {
            ArrayResize(array_5d.books[book].volumes[volume].pages[page].rows, row_size);

            for(int row = 0; row < row_size; row++)
              {
               ArrayResize(array_5d.books[book].volumes[volume].pages[page].rows[row].data, data_size);

               // データを設定
               for(int col = 0; col < data_size; col++)
                 {
                  array_5d.books[book].volumes[volume].pages[page].rows[row].data[col] =
                     StringFormat("B%dV%dP%dR%dC%d", book, volume, page, row, col);
                 }
              }
           }
        }
      
      Comment("初期化進行中: ", book * 100 / book_size, "%");
     }

   Print("5次元配列初期化完了");
   
   // データアクセス例
   Print("array_5d[0][1][2][3][4] = ", array_5d.books[0].volumes[1].pages[2].rows[3].data[4]);
   
   // データ変更例
   array_5d.books[0].volumes[1].pages[2].rows[3].data[4] = "変更されたデータ";
   Print("変更後: ", array_5d.books[0].volumes[1].pages[2].rows[3].data[4]);
  }